Вибори

Оформлення

Щоб змінити оформлення варіантів вибору, використовуйте глобальний тег #choices:

# choices: grouped numbered left

Щоб змінити оформлення варіантів вибору лише для поточної сцени, використовуйте тег параграфу #CHOICES:

=== combat
# CHOICES: grouped row
Ворог чекає.
+ [Атакувати] -> combat_attack
+ [Захищатися] -> combat_defend
+ [Ухилитися] -> combat_evade

Ці теги мають такі атрибути:

Атрибут	Опис
grouped	Згрупувати кнопки варіантів вибору.
numbered	Показати номер варіанту вибору перед його текстом.
left	Вирівняти текст варіантів вибору ліворуч.
right	Вирівняти текст варіантів вибору праворуч.
row	Показати кнопки варіантів виборів в один рядок.

Перемішані варіанти

Ви можете перемішати варіанти виборів за допомогою тегу параграфу #SHUFFLE_CHOICES; це може знадобитися для загадок. Тег застосовується до варіантів виборів, що з'являються після поточної сцени.

=== guess_the_color
# SHUFFLE_CHOICES
Якого кольору листя та трава?
+ [Червоний] -> wrong_choice
+ [Помаранчевий] -> wrong_choice
+ [Жовтий] -> wrong_choice
+ [Зелений] -> right_choice
+ [Синій] -> wrong_choice
+ [Фіолетовий] -> wrong_choice

Підказка

Ви можете показати підказку перед варіантами вибору за допомогою тега параграфу #PROMPT. Тег застосовується до варіантів виборів, що з'являються після поточної сцени.

=== combat
// цей текст буде показаний перед варіантами вибору
# PROMPT: Що будете робити?
Ворог чекає.
+ [Атакувати] -> combat_attack
+ [Захищатися] -> combat_defend
+ [Ухилитися] -> combat_evade

Неактивні варіанти

Замість того, щоб ховати варіант вибору в залежності від умови, ви можете зробити його неактивним за допомогою тега вибору #UNCLICKABLE (альтернативний синтаксис: #DISABLED, #INACTIVE). Варіант вибору буде показаний неактивним, і його не можна буде обрати.

VAR weapon = "sword"
-> story
=== story
{weapon == "sword":Ви тримаєте меч|Ви неозброєні}.
// Варіанти вибору будуть неактивними
// в залежності від значення змінної "weapon"
+ [Атакувати #{weapon == "":UNCLICKABLE}]
    Ви розмахуєте мечем.
    -> story
+ [Витягти меч #{weapon == "sword":UNCLICKABLE}]
    ~ weapon = "sword"
    -> story
+ [Сховати зброю #{weapon == "":UNCLICKABLE}]
    ~ weapon = ""
    -> story
+ [Повернутися до подорожі #UNCLICKABLE] // цей варіант неактивний завжди
    -> story

Приховані варіанти

Вм можете ховати варіанти вибору від гравця за допомогою тега вибору #HIDDEN. Варіант вибору не буде показаний гравцеві і його неможливо буде обрати звичайним способом. Прихований варіант вибору можна обрати за допомогою тега розмітки [link] або тега параграфу #AUTO_CHOICE.

=== combat
Ворог чекає.
+ [Атакувати] -> combat_attack
+ [Захищатися] -> combat_defend
+ [Ухилитися#HIDDEN] -> combat_evade // цей варіант буде прихований

Автоматичний вибір

Ви можете автоматично обрати заданий вами або випадковий варіант вибору за допомогою тега параграфу #AUTO_CHOICE:

# AUTO_CHOICE: delay=10 choice="Варіант вибору"

Атрибут	Опис
delay	Задає паузу перед автоматичним вибором. На екран буде показаний індикатор часу. Якщо атрибут не вказаний, вибір робиться без затримки.
choice	Текст того варіанту вибору, який має бути вибраний автоматично. Якщо атрибут не вказаний, буде обраний випадковий варіант вибору.

Натисніть, щоб продовжити

Одиночний варіант вибору з текстом >>> використовується для створення "натисніть, щоб продовжити". Кнопки з варіантами вибору будуть відсутні, і гравець може продовжити історію за допомогою кліка по екрану чи натисканню клавіш "Пробіл" або "Enter". Після 3 секунд неактивності внизу екрана з'явиться анімована підказка.

Ця історія продовжиться, коли гравець буде готовий.
+ [>>>] -> next_knot

Ви також можете вказати затримку в секундах. Такий вибір буде відображатися іншою круглою кнопкою. Після затримки історія продовжиться автоматично.

Ця історія продовжиться, коли гравець щось натисне, або ж через 3 секунди.
+ [>>>3] -> next_knot

Вибір "натисніть, щоб продовжити" можна налаштувати під себе за допомогою атрибутів:

• clickable - пауза перед тим, як можна буде продовжити історію. Якщо не вказано, гравець може продовжити історію негайно.
• animation - пауза перед анімацією підказки. Якщо не вказано, анімована підказка показується відразу.
• continue - пауза перед автоматичним продовженням історії. Якщо не вказано, історія продовжується лише після кліку або натискання клавіші.

Всі паузи вказуються в секундах.

+ [>>>(clickable=3 animation=5 continue=10)] -> next_knot